здравейте колеги, много ме измъчва една задача и нямам никаква идея как да я направя.

задачата е следната: Да се разменят стойностите на елементите с най-малка и най-голяма стойност в отделните стълбове на двумерен масив с m реда и n стълба.

Редактирано 16 ноември 20169 г. от deva19722 (преглед на промените)

program minmax;
const
   MaxR = 16;
   MaxC = 16;
var
   i,j,m,n : integer;
   A : array [1..MaxR,1..MaxC] of integer;

procedure Swap(c : integer);
var
   i, min, max : integer;
begin
   min := 1;
   max := 1;
   for i:=2 to m do
      if A[i,c]<A[min,c] then min := i
      else if A[i,c]>A[max,c] then max := i;
   i := A[min,c];
   A[min,c] := A[max,c];
   A[max,c] := i;
end; {Swap}

procedure Print;
var
   i, j: integer;
begin
   for i:=1 to m do
   begin
      for j:=1 to n do Write(A[i,j]:5);
      writeln;
   end;
   writeln;
end;  {Print}

begin
   repeat
      Write('m [2..',MaxR,'] = ');
      ReadLn(m);
   until (m>1)and(m<=MaxR);
   repeat
      Write('n [2..',MaxC,'] = ');
      Readln(n);
   until (n>1)and(n<=MaxC);

   for i:=1 to m do
   begin
      for j:=1 to n do
      begin
         Write('A[',i,',',j,'] = ');
         Readln(a[i,j]);
      end;
      Writeln;
   end;

   Print;
   writeln('Swap');
   Writeln;
   for i:=1 to n do Swap(i);
   Print;
end.

 

Редактирано 18 ноември 20169 г. от ined (преглед на промените)

много благодаря колега, задачата работи идеално, само имам въпрос, ще можеш ли да ми кажеш от къде мога да си намеря информация за създаване на програма на паскал чиято задача да е да използва подпрограми

Редактирано 1 декември 20169 г. от deva19722 (преглед на промените)